title screen and transition

leafo · leafo · commit f8a32b3bbb8b · 2012-04-22T10:34:04.000-07:00
diff --git a/main.moon b/main.moon
@@ -66,7 +66,7 @@ class World
   collides: (thing) =>
     @bg\collides thing
 
-class Game
+export class Game
   new: =>
     @viewport = EffectViewport scale: 4
 
@@ -95,22 +95,26 @@ class Game
 snapper = nil
 
 love.load = ->
-  export game = Game!
+  export dispatch = Dispatch TitleScreen!
+  -- export game = Game!
 
   font_image = imgfy"img/font.png"
 
   font = g.newImageFont font_image.tex, " 1234567890"
   g.setFont font
 
   love.mousepressed = (x,y, button) ->
-    x, y = game.viewport\unproject x, y
-    -- emitters.PourSmoke\add w, x, y
+    if game
+      x, y = game.viewport\unproject x, y
+      -- emitters.PourSmoke\add w, x, y
 
   love.keypressed = (key, code) ->
+    return if dispatch\send_key key, code
+
     switch key
       when "escape" then os.exit!
       when "d"
-        game.player\die!
+        game.player\die! if game
       when "x" -- cool
         if snapper
           slow_mode = false
@@ -125,9 +129,9 @@ love.load = ->
   love.update = (dt) ->
     reloader\update!
     dt /= 3 if slow_mode
-    game\update dt
+    dispatch\update dt
 
   love.draw = ->
     snapper\tick! if snapper
-    game\draw!
+    dispatch\draw!
 
diff --git a/ui.moon b/ui.moon
@@ -1,14 +1,88 @@
 
 g = love.graphics
 import timer, keyboard from love
+import insert, remove from table
 
 export *
 
-class Dispatch -- this holds the stack of stuff
-  nil
+-- ugh
+fade_effect = (prev, current, t) ->
+  t = smoothstep 0, 1, t
+
+  if t < 0.5
+    prev\draw!
+
+    g.setColor 0,0,0, 255 * t * 2
+    g.rectangle "fill", 0,0, g.getWidth!, g.getHeight!
+    g.setColor 255,255,255,255
+  else
+    current\draw!
+
+    g.setColor 0,0,0, 255 * (1 - t) * 2
+    g.rectangle "fill", 0,0, g.getWidth!, g.getHeight!
+    g.setColor 255,255,255,255
+
+class Dispatch
+  new: (initial) =>
+    @stack = { initial }
+
+  send: (event, ...) =>
+    current = @top!
+    current[event] current, ... if current and current[event]
+
+  send_key: (...) => @send "on_key", ...
+
+  top: => @stack[#@stack]
+  parent: => @stack[#@stack - 1]
+
+  push: (state) =>
+    @blend_effect = nil
+    insert @stack, state
+
+  push_with_effect: (state, time, efx) =>
+    @elapsed = 0
+    @effect_time = time
+
+    prev = @top!
+    @blend_effect = (t) => efx prev, state, t
+
+    insert @stack, state
+
+  pop: =>
+    @blend_effect = nil
+
+    os.exit! if #stack == 0
+    remove @stack
+
+  draw: =>
+    if @blend_effect
+      @blend_effect @elapsed / @effect_time
+    else
+      @send "draw"
+
+  update: (dt) =>
+    if @blend_effect
+      @elapsed += dt
+      @blend_effect = nil if @elapsed > @effect_time
+
+    @send "update", dt
 
 class TitleScreen
-  nil
+  new: =>
+    @viewport = Viewport scale: 4
+    @img = imgfy"img/title.png"
+
+  on_key: (key) =>
+    switch key
+      when "escape" then os.exit!
+      when "return" then @start_game!
+
+  start_game: =>
+    dispatch\push_with_effect Game!, 1, fade_effect
+
+  draw: =>
+    @viewport\apply!
+    @img\draw 0, 0
 
 class GameOver
   high_scores: {
@@ -65,6 +139,6 @@ class Hud
     if @display_score < @score
       @display_score += dt * math.max 200, @score - @display_score
       @display_score = math.min @display_score, @score
-    
+
     @health_bar.value = @player.health / @player.max_health
 
