forked from SeasideSt/Grease
-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathGRPrinter.class.st
More file actions
330 lines (277 loc) · 8.82 KB
/
GRPrinter.class.st
File metadata and controls
330 lines (277 loc) · 8.82 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
Class {
#name : #GRPrinter,
#superclass : #GRObject,
#category : 'Grease-Core-Text'
}
{ #category : #'parts-date' }
GRPrinter class >> abbreviatedMonthName [
^ self monthName: #('Jan' 'Feb' 'Mar' 'Apr' 'May' 'Jun' 'Jul' 'Aug' 'Sep' 'Oct' 'Nov' 'Dec')
]
{ #category : #'parts-date' }
GRPrinter class >> abbreviatedWeekName [
^ self weekName: #('Sun' 'Mon' 'Tue' 'Wed' 'Thu' 'Fri' 'Sat')
]
{ #category : #'parts-date' }
GRPrinter class >> absOffsetHoursPadded [
^ GRMappedPrinter
block: [ :date | date offset hours abs ]
next: (self numberWithAtLeastDigits: 2)
]
{ #category : #'parts-date' }
GRPrinter class >> absOffsetMinutesPadded [
^ GRMappedPrinter
block: [ :date | date offset minutes abs ]
next: (self numberWithAtLeastDigits: 2)
]
{ #category : #'parts-units' }
GRPrinter class >> binaryFileSize [
^ GRUnitPrinter base: 1024 units: #('byte' 'bytes' 'KiB' 'MiB' 'GiB' 'TiB' 'PiB' 'EiB' 'ZiB' 'YiB')
]
{ #category : #'factory-http' }
GRPrinter class >> cookieTimestamp [
"Netscape's original proposal defined an Expires header that took a date value in a fixed-length variant format in place of Max-Age: Wdy, DD-Mon-YY HH:MM:SS GMT"
^ GRMappedPrinter
block: [ :timestamp | timestamp asUTC ]
next: self abbreviatedWeekName , ', ' , self paddedDay , '-' , self abbreviatedMonthName , '-' , self paddedYear , ' ' , self isoTime , ' GMT'
]
{ #category : #'parts-units' }
GRPrinter class >> decimalFileSize [
^ GRUnitPrinter base: 1000 units: #('byte' 'bytes' 'kB' 'MB' 'GB' 'TB' 'PB' 'EB' 'ZB' 'YB')
]
{ #category : #'parts-date' }
GRPrinter class >> fullMonthName [
^ self monthName: #('January' 'February' 'March' 'April' 'May' 'June' 'July' 'August' 'September' 'October' 'November' 'December')
]
{ #category : #'parts-date' }
GRPrinter class >> fullWeekName [
^ self weekName: #('Sunday' 'Monday' 'Tuesday' 'Wednesday' 'Thursday' 'Friday' 'Saturday')
]
{ #category : #'factory-http' }
GRPrinter class >> httpDate [
"Answers a printer that formats dates for HTTP1.1 (RFC 2616)"
^ self rfc1123
]
{ #category : #'factory-http' }
GRPrinter class >> isoDate [
"Ansers a printer that formats dates according to ISO(YYYY-MM-DD) E.g. 2003-12-24"
^ self paddedYear , $- , self paddedMonth , $- , self paddedDay
]
{ #category : #'factory-http' }
GRPrinter class >> isoTime [
"Ansers a printer that formats time according to ISO(HH:MM:SS) E.g. 12:23:34"
^ self paddedHour24 , $: , self paddedMinute , $: , self paddedSecond
]
{ #category : #'parts-date' }
GRPrinter class >> monthName: anArray [
^ GRPluggablePrinter on: [ :date | anArray at: date monthIndex ]
]
{ #category : #'parts-units' }
GRPrinter class >> numberWithAtLeastDigits: anInteger [
^ GRNumberPrinter new
padding: $0;
digits: anInteger;
yourself
]
{ #category : #'parts-date' }
GRPrinter class >> offsetSign [
^ GRMappedPrinter
block: [ :date | date offset ]
next: (GRSignPrinter new
positivePrinter: $+;
negativePrinter: $-;
yourself)
]
{ #category : #'parts-date' }
GRPrinter class >> paddedCentury [
^ GRMappedPrinter
block: [ :date | date year \\ 100 ]
next: (self numberWithAtLeastDigits: 2)
]
{ #category : #'parts-date' }
GRPrinter class >> paddedDay [
^ GRMappedPrinter
block: [ :date | date dayOfMonth ]
next: (self numberWithAtLeastDigits: 2)
]
{ #category : #'parts-time' }
GRPrinter class >> paddedHour12 [
^ GRMappedPrinter
block: [ :time | (time hour - 1) \\ 12 + 1 ]
next: (self numberWithAtLeastDigits: 2)
]
{ #category : #'parts-time' }
GRPrinter class >> paddedHour24 [
^ GRMappedPrinter
block: [ :time | time hour ]
next: (self numberWithAtLeastDigits: 2)
]
{ #category : #'parts-time' }
GRPrinter class >> paddedMinute [
^ GRMappedPrinter
block: [ :time | time minute ]
next: (self numberWithAtLeastDigits: 2)
]
{ #category : #'parts-date' }
GRPrinter class >> paddedMonth [
^ GRMappedPrinter
block: [ :date | date monthIndex ]
next: (self numberWithAtLeastDigits: 2)
]
{ #category : #'parts-time' }
GRPrinter class >> paddedSecond [
^ GRMappedPrinter
block: [ :time | time second ]
next: (GRNumberPrinter new
padding: $0;
digits: 2)
]
{ #category : #'parts-date' }
GRPrinter class >> paddedYear [
^ GRMappedPrinter
block: [ :date | date year ]
next: (self numberWithAtLeastDigits: 4)
]
{ #category : #'factory-http' }
GRPrinter class >> rfc1123 [
"Answers a printer that formats dates for HTTP1.1 (RFC 1123). Eg.
Sun, 06 Nov 1994 08:49:37 GMT "
^ GRMappedPrinter
block: [ :date |
"For the purposes of HTTP, GMT is exactly equal to UTC (Coordinated Universal Time)"
date asUTC ]
next: GRSequentialPrinter new , self abbreviatedWeekName , ', ' , self paddedDay , Character space , self abbreviatedMonthName , Character space , self paddedYear , Character space , self isoTime , ' GMT'
]
{ #category : #'factory-http' }
GRPrinter class >> rfc822 [
"Answers a printer that formats dates according to RFC 822 (email). Eg.
Sun, 31 Aug 2008 19:41:46 +0200"
^ self abbreviatedWeekName , ', ' , self paddedDay , Character space , self abbreviatedMonthName , Character space , self paddedYear , Character space , self isoTime , Character space , self offsetSign , self absOffsetHoursPadded , self absOffsetMinutesPadded
]
{ #category : #'factory-http' }
GRPrinter class >> rfc822WithTimeZone: aString [
"Answers a privter that formats dates according to RFC 822 (email) with the given time zone String. Eg.
Sun, 31 Aug 2008 19:41:46 <aString>"
^ self abbreviatedWeekName , ', ' , self paddedDay , Character space , self abbreviatedMonthName , Character space , self paddedYear , Character space , self isoTime , Character space , aString
]
{ #category : #'factory-currency' }
GRPrinter class >> swissCurrency [
^ GRSequentialPrinter new , 'CHF ' , GRSignPrinter new , (GRNumberPrinter new
separator: $';
precision: 2;
accuracy: 0.05;
yourself)
]
{ #category : #'parts-date' }
GRPrinter class >> unpaddedCentury [
^ GRMappedPrinter
block: [ :date | date year \\ 100 ]
next: GRNumberPrinter new
]
{ #category : #'parts-date' }
GRPrinter class >> unpaddedDay [
^ GRMappedPrinter
block: [ :date | date dayOfMonth ]
next: GRNumberPrinter new
]
{ #category : #'parts-time' }
GRPrinter class >> unpaddedHour12 [
^ GRMappedPrinter
block: [ :time | (time hour - 1) \\ 12 + 1 ]
next: GRNumberPrinter new
]
{ #category : #'parts-time' }
GRPrinter class >> unpaddedHour24 [
^ GRMappedPrinter
block: [ :time | time hour ]
next: GRNumberPrinter new
]
{ #category : #'parts-time' }
GRPrinter class >> unpaddedMinute [
^ GRMappedPrinter
block: [ :time | time minute ]
next: GRNumberPrinter new
]
{ #category : #'parts-date' }
GRPrinter class >> unpaddedMonth [
^ GRMappedPrinter
block: [ :date | date monthIndex ]
next: GRNumberPrinter new
]
{ #category : #'parts-time' }
GRPrinter class >> unpaddedSecond [
^ GRMappedPrinter
block: [ :time | time second ]
next: GRNumberPrinter new
]
{ #category : #'parts-date' }
GRPrinter class >> unpaddedYear [
^ GRMappedPrinter
block: [ :date | date year ]
next: GRNumberPrinter new
]
{ #category : #'factory-currency' }
GRPrinter class >> usCurrency [
^ GRSignPrinter new , $$ , (GRNumberPrinter new
separator: $,;
precision: 2;
yourself)
]
{ #category : #'parts-date' }
GRPrinter class >> weekName: anArray [
^ GRPluggablePrinter on: [ :date | anArray at: date dayOfWeek ]
]
{ #category : #operators }
GRPrinter >> , aPrinter [
^ GRSequentialPrinter new , self , aPrinter
]
{ #category : #utilities }
GRPrinter >> pad: aString center: aCharacter to: anInteger [
"Pad to the center of aString with aCharacter to at least anInteger characters."
| result index |
anInteger <= aString size
ifTrue: [ ^ aString ].
index := (anInteger - aString size) // 2.
result := (String new: anInteger) atAllPut: aCharacter.
result
replaceFrom: index + 1
to: index + aString size
with: aString
startingAt: 1.
^ result
]
{ #category : #utilities }
GRPrinter >> pad: aString left: aCharacter to: anInteger [
"Pad to the left side of aString with aCharacter to at least anInteger characters."
| result |
anInteger <= aString size
ifTrue: [ ^ aString ].
result := (String new: anInteger) atAllPut: aCharacter.
result
replaceFrom: anInteger - aString size + 1
to: anInteger
with: aString
startingAt: 1.
^ result
]
{ #category : #utilities }
GRPrinter >> pad: aString right: aCharacter to: anInteger [
"Pad to the right side of aString with aCharacter to at least anInteger characters."
| result |
anInteger <= aString size
ifTrue: [ ^ aString ].
result := (String new: anInteger) atAllPut: aCharacter.
result
replaceFrom: 1
to: aString size
with: aString
startingAt: 1.
^ result
]
{ #category : #printing }
GRPrinter >> print: anObject [
^ String streamContents: [ :stream | self print: anObject on: stream ]
]
{ #category : #printing }
GRPrinter >> print: anObject on: aStream [
"Subclasses override this method to produce some output."
]