forked from apache/arrow
-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathtypes.pxi
More file actions
1160 lines (890 loc) · 28.1 KB
/
types.pxi
File metadata and controls
1160 lines (890 loc) · 28.1 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# Licensed to the Apache Software Foundation (ASF) under one
# or more contributor license agreements. See the NOTICE file
# distributed with this work for additional information
# regarding copyright ownership. The ASF licenses this file
# to you under the Apache License, Version 2.0 (the
# "License"); you may not use this file except in compliance
# with the License. You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing,
# software distributed under the License is distributed on an
# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
# KIND, either express or implied. See the License for the
# specific language governing permissions and limitations
# under the License.
# These are imprecise because the type (in pandas 0.x) depends on the presence
# of nulls
cdef dict _pandas_type_map = {
_Type_NA: np.float64, # NaNs
_Type_BOOL: np.bool_,
_Type_INT8: np.int8,
_Type_INT16: np.int16,
_Type_INT32: np.int32,
_Type_INT64: np.int64,
_Type_UINT8: np.uint8,
_Type_UINT16: np.uint16,
_Type_UINT32: np.uint32,
_Type_UINT64: np.uint64,
_Type_HALF_FLOAT: np.float16,
_Type_FLOAT: np.float32,
_Type_DOUBLE: np.float64,
_Type_DATE32: np.dtype('datetime64[ns]'),
_Type_DATE64: np.dtype('datetime64[ns]'),
_Type_TIMESTAMP: np.dtype('datetime64[ns]'),
_Type_BINARY: np.object_,
_Type_FIXED_SIZE_BINARY: np.object_,
_Type_STRING: np.object_,
_Type_LIST: np.object_,
_Type_DECIMAL: np.object_,
}
cdef class DataType:
"""
Base type for Apache Arrow data type instances. Wraps C++ arrow::DataType
"""
def __cinit__(self):
pass
cdef void init(self, const shared_ptr[CDataType]& type):
self.sp_type = type
self.type = type.get()
property id:
def __get__(self):
return self.type.id()
def __str__(self):
if self.type is NULL:
raise TypeError(
'{} is incomplete. The correct way to construct types is '
'through public API functions named '
'pyarrow.int64, pyarrow.list_, etc.'.format(
type(self).__name__
)
)
return frombytes(self.type.ToString())
def __reduce__(self):
return self.__class__, (), self.__getstate__()
def __getstate__(self):
return str(self),
def __setstate__(self, state):
cdef DataType reconstituted = type_for_alias(state[0])
self.init(reconstituted.sp_type)
def __repr__(self):
return '{0.__class__.__name__}({0})'.format(self)
def __richcmp__(DataType self, object other, int op):
if op == cp.Py_EQ:
return self.equals(other)
elif op == cp.Py_NE:
return not self.equals(other)
else:
raise TypeError('Invalid comparison')
def equals(self, other):
"""
Return true if type is equivalent to passed value
Parameters
----------
other : DataType or string convertible to DataType
Returns
-------
is_equal : boolean
"""
cdef DataType other_type
if not isinstance(other, DataType):
if not isinstance(other, six.string_types):
raise TypeError(other)
other_type = type_for_alias(other)
else:
other_type = other
return self.type.Equals(deref(other_type.type))
def to_pandas_dtype(self):
"""
Return the NumPy dtype that would be used for storing this
"""
cdef Type type_id = self.type.id()
if type_id in _pandas_type_map:
return _pandas_type_map[type_id]
else:
raise NotImplementedError(str(self))
cdef class DictionaryType(DataType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
self.dict_type = <const CDictionaryType*> type.get()
property ordered:
def __get__(self):
return self.dict_type.ordered()
cdef class ListType(DataType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
self.list_type = <const CListType*> type.get()
def __getstate__(self):
cdef CField* field = self.list_type.value_field().get()
name = field.name()
return name, self.value_type
def __setstate__(self, state):
cdef DataType reconstituted = list_(field(state[0], state[1]))
self.init(reconstituted.sp_type)
property value_type:
def __get__(self):
return pyarrow_wrap_data_type(self.list_type.value_type())
cdef class StructType(DataType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
def __getitem__(self, i):
if i < 0 or i >= self.num_children:
raise IndexError(i)
return pyarrow_wrap_field(self.type.child(i))
property num_children:
def __get__(self):
return self.type.num_children()
def __getstate__(self):
cdef CStructType* type = <CStructType*> self.sp_type.get()
return [self[i] for i in range(self.num_children)]
def __setstate__(self, state):
cdef DataType reconstituted = struct(state)
self.init(reconstituted.sp_type)
cdef class UnionType(DataType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
cdef class TimestampType(DataType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
self.ts_type = <const CTimestampType*> type.get()
property unit:
def __get__(self):
return timeunit_to_string(self.ts_type.unit())
property tz:
def __get__(self):
if self.ts_type.timezone().size() > 0:
return frombytes(self.ts_type.timezone())
else:
return None
def to_pandas_dtype(self):
"""
Return the NumPy dtype that would be used for storing this
"""
if self.tz is None:
return _pandas_type_map[_Type_TIMESTAMP]
else:
# Return DatetimeTZ
return pdcompat.make_datetimetz(self.tz)
cdef class Time32Type(DataType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
self.time_type = <const CTime32Type*> type.get()
property unit:
def __get__(self):
return timeunit_to_string(self.time_type.unit())
cdef class Time64Type(DataType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
self.time_type = <const CTime64Type*> type.get()
property unit:
def __get__(self):
return timeunit_to_string(self.time_type.unit())
cdef class FixedSizeBinaryType(DataType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
self.fixed_size_binary_type = (
<const CFixedSizeBinaryType*> type.get())
def __getstate__(self):
return self.byte_width
def __setstate__(self, state):
cdef DataType reconstituted = binary(state)
self.init(reconstituted.sp_type)
property byte_width:
def __get__(self):
return self.fixed_size_binary_type.byte_width()
cdef class DecimalType(FixedSizeBinaryType):
cdef void init(self, const shared_ptr[CDataType]& type):
DataType.init(self, type)
self.decimal_type = <const CDecimalType*> type.get()
def __getstate__(self):
return (self.precision, self.scale)
def __setstate__(self, state):
cdef DataType reconstituted = decimal(*state)
self.init(reconstituted.sp_type)
property precision:
def __get__(self):
return self.decimal_type.precision()
property scale:
def __get__(self):
return self.decimal_type.scale()
cdef class Field:
"""
Represents a named field, with a data type, nullability, and optional
metadata
Notes
-----
Do not use this class's constructor directly; use pyarrow.field
"""
def __cinit__(self):
pass
cdef void init(self, const shared_ptr[CField]& field):
self.sp_field = field
self.field = field.get()
self.type = pyarrow_wrap_data_type(field.get().type())
def equals(self, Field other):
"""
Test if this field is equal to the other
"""
return self.field.Equals(deref(other.field))
def __richcmp__(Field self, Field other, int op):
if op == cp.Py_EQ:
return self.equals(other)
elif op == cp.Py_NE:
return not self.equals(other)
else:
raise TypeError('Invalid comparison')
def __reduce__(self):
return Field, (), self.__getstate__()
def __getstate__(self):
return (self.name, self.type, self.metadata)
def __setstate__(self, state):
cdef Field reconstituted = field(state[0], state[1], metadata=state[2])
self.init(reconstituted.sp_field)
def __str__(self):
self._check_null()
return 'pyarrow.Field<{0}>'.format(frombytes(self.field.ToString()))
def __repr__(self):
return self.__str__()
property nullable:
def __get__(self):
self._check_null()
return self.field.nullable()
property name:
def __get__(self):
self._check_null()
return frombytes(self.field.name())
property metadata:
def __get__(self):
self._check_null()
cdef shared_ptr[const CKeyValueMetadata] metadata = (
self.field.metadata())
return box_metadata(metadata.get())
def _check_null(self):
if self.field == NULL:
raise ReferenceError(
'Field not initialized (references NULL pointer)')
def add_metadata(self, dict metadata):
"""
Add metadata as dict of string keys and values to Field
Parameters
----------
metadata : dict
Keys and values must be string-like / coercible to bytes
Returns
-------
field : pyarrow.Field
"""
cdef shared_ptr[CKeyValueMetadata] c_meta
convert_metadata(metadata, &c_meta)
cdef shared_ptr[CField] new_field
with nogil:
new_field = self.field.AddMetadata(c_meta)
return pyarrow_wrap_field(new_field)
def remove_metadata(self):
"""
Create new field without metadata, if any
Returns
-------
field : pyarrow.Field
"""
cdef shared_ptr[CField] new_field
with nogil:
new_field = self.field.RemoveMetadata()
return pyarrow_wrap_field(new_field)
cdef class Schema:
def __cinit__(self):
pass
def __len__(self):
return self.schema.num_fields()
def __getitem__(self, int i):
cdef:
Field result = Field()
int num_fields = self.schema.num_fields()
int index
if not -num_fields <= i < num_fields:
raise IndexError(
'Schema field index {:d} is out of range'.format(i)
)
index = i if i >= 0 else num_fields + i
assert index >= 0
result.init(self.schema.field(index))
result.type = pyarrow_wrap_data_type(result.field.type())
return result
def __iter__(self):
for i in range(len(self)):
yield self[i]
def _check_null(self):
if self.schema == NULL:
raise ReferenceError(
'Schema not initialized (references NULL pointer)')
cdef void init(self, const vector[shared_ptr[CField]]& fields):
self.schema = new CSchema(fields)
self.sp_schema.reset(self.schema)
cdef void init_schema(self, const shared_ptr[CSchema]& schema):
self.schema = schema.get()
self.sp_schema = schema
def __reduce__(self):
return Schema, (), self.__getstate__()
def __getstate__(self):
return ([self[i] for i in range(len(self))], self.metadata)
def __setstate__(self, state):
cdef Schema reconstituted = schema(state[0], metadata=state[1])
self.init_schema(reconstituted.sp_schema)
property names:
def __get__(self):
cdef int i
result = []
for i in range(self.schema.num_fields()):
name = frombytes(self.schema.field(i).get().name())
result.append(name)
return result
property metadata:
def __get__(self):
self._check_null()
cdef shared_ptr[const CKeyValueMetadata] metadata = (
self.schema.metadata())
return box_metadata(metadata.get())
def __richcmp__(self, other, int op):
if op == cp.Py_EQ:
return self.equals(other)
elif op == cp.Py_NE:
return not self.equals(other)
else:
raise TypeError('Invalid comparison')
def equals(self, other):
"""
Test if this schema is equal to the other
"""
cdef Schema _other
_other = other
return self.sp_schema.get().Equals(deref(_other.schema))
def field_by_name(self, name):
"""
Access a field by its name rather than the column index.
Parameters
----------
name: str
Returns
-------
field: pyarrow.Field
"""
return pyarrow_wrap_field(self.schema.GetFieldByName(tobytes(name)))
def get_field_index(self, name):
return self.schema.GetFieldIndex(tobytes(name))
def add_metadata(self, dict metadata):
"""
Add metadata as dict of string keys and values to Schema
Parameters
----------
metadata : dict
Keys and values must be string-like / coercible to bytes
Returns
-------
schema : pyarrow.Schema
"""
cdef shared_ptr[CKeyValueMetadata] c_meta
convert_metadata(metadata, &c_meta)
cdef shared_ptr[CSchema] new_schema
with nogil:
new_schema = self.schema.AddMetadata(c_meta)
return pyarrow_wrap_schema(new_schema)
def serialize(self, memory_pool=None):
"""
Write Schema to Buffer as encapsulated IPC message
Parameters
----------
memory_pool : MemoryPool, default None
Uses default memory pool if not specified
Returns
-------
serialized : Buffer
"""
cdef:
shared_ptr[CBuffer] buffer
CMemoryPool* pool = maybe_unbox_memory_pool(memory_pool)
with nogil:
check_status(SerializeSchema(deref(self.schema),
pool, &buffer))
return pyarrow_wrap_buffer(buffer)
def remove_metadata(self):
"""
Create new schema without metadata, if any
Returns
-------
schema : pyarrow.Schema
"""
cdef shared_ptr[CSchema] new_schema
with nogil:
new_schema = self.schema.RemoveMetadata()
return pyarrow_wrap_schema(new_schema)
def __str__(self):
self._check_null()
cdef:
PrettyPrintOptions options
c_string result
options.indent = 0
with nogil:
check_status(PrettyPrint(deref(self.schema), options, &result))
printed = frombytes(result)
if self.metadata is not None:
import pprint
metadata_formatted = pprint.pformat(self.metadata)
printed += '\nmetadata\n--------\n' + metadata_formatted
return printed
def __repr__(self):
return self.__str__()
cdef dict box_metadata(const CKeyValueMetadata* metadata):
cdef unordered_map[c_string, c_string] result
if metadata != nullptr:
metadata.ToUnorderedMap(&result)
return result
else:
return None
cdef dict _type_cache = {}
cdef DataType primitive_type(Type type):
if type in _type_cache:
return _type_cache[type]
cdef DataType out = DataType()
out.init(GetPrimitiveType(type))
_type_cache[type] = out
return out
# -----------------------------------------------------------
# Type factory functions
cdef int convert_metadata(dict metadata,
shared_ptr[CKeyValueMetadata]* out) except -1:
cdef:
shared_ptr[CKeyValueMetadata] meta = (
make_shared[CKeyValueMetadata]())
c_string key, value
for py_key, py_value in metadata.items():
key = tobytes(py_key)
value = tobytes(py_value)
meta.get().Append(key, value)
out[0] = meta
return 0
def field(name, type, bint nullable=True, dict metadata=None):
"""
Create a pyarrow.Field instance
Parameters
----------
name : string or bytes
type : pyarrow.DataType
nullable : boolean, default True
metadata : dict, default None
Keys and values must be coercible to bytes
Returns
-------
field : pyarrow.Field
"""
cdef:
shared_ptr[CKeyValueMetadata] c_meta
Field result = Field()
DataType _type
if metadata is not None:
convert_metadata(metadata, &c_meta)
_type = _as_type(type)
result.sp_field.reset(new CField(tobytes(name), _type.sp_type,
nullable == 1, c_meta))
result.field = result.sp_field.get()
result.type = _type
return result
cdef _as_type(type):
if isinstance(type, DataType):
return type
if not isinstance(type, six.string_types):
raise TypeError(type)
return type_for_alias(type)
cdef set PRIMITIVE_TYPES = set([
_Type_NA, _Type_BOOL,
_Type_UINT8, _Type_INT8,
_Type_UINT16, _Type_INT16,
_Type_UINT32, _Type_INT32,
_Type_UINT64, _Type_INT64,
_Type_TIMESTAMP, _Type_DATE32,
_Type_TIME32, _Type_TIME64,
_Type_DATE64,
_Type_HALF_FLOAT,
_Type_FLOAT,
_Type_DOUBLE])
def null():
"""
Create instance of null type
"""
return primitive_type(_Type_NA)
def bool_():
"""
Create instance of boolean type
"""
return primitive_type(_Type_BOOL)
def uint8():
"""
Create instance of boolean type
"""
return primitive_type(_Type_UINT8)
def int8():
"""
Create instance of signed int8 type
"""
return primitive_type(_Type_INT8)
def uint16():
"""
Create instance of unsigned uint16 type
"""
return primitive_type(_Type_UINT16)
def int16():
"""
Create instance of signed int16 type
"""
return primitive_type(_Type_INT16)
def uint32():
"""
Create instance of unsigned uint32 type
"""
return primitive_type(_Type_UINT32)
def int32():
"""
Create instance of signed int32 type
"""
return primitive_type(_Type_INT32)
def uint64():
"""
Create instance of unsigned uint64 type
"""
return primitive_type(_Type_UINT64)
def int64():
"""
Create instance of signed int64 type
"""
return primitive_type(_Type_INT64)
cdef dict _timestamp_type_cache = {}
cdef dict _time_type_cache = {}
cdef timeunit_to_string(TimeUnit unit):
if unit == TimeUnit_SECOND:
return 's'
elif unit == TimeUnit_MILLI:
return 'ms'
elif unit == TimeUnit_MICRO:
return 'us'
elif unit == TimeUnit_NANO:
return 'ns'
def timestamp(unit, tz=None):
"""
Create instance of timestamp type with resolution and optional time zone
Parameters
----------
unit : string
one of 's' [second], 'ms' [millisecond], 'us' [microsecond], or 'ns'
[nanosecond]
tz : string, default None
Time zone name. None indicates time zone naive
Examples
--------
::
t1 = pa.timestamp('us')
t2 = pa.timestamp('s', tz='America/New_York')
Returns
-------
timestamp_type : TimestampType
"""
cdef:
TimeUnit unit_code
c_string c_timezone
if unit == "s":
unit_code = TimeUnit_SECOND
elif unit == 'ms':
unit_code = TimeUnit_MILLI
elif unit == 'us':
unit_code = TimeUnit_MICRO
elif unit == 'ns':
unit_code = TimeUnit_NANO
else:
raise ValueError('Invalid TimeUnit string')
cdef TimestampType out = TimestampType()
if tz is None:
out.init(ctimestamp(unit_code))
if unit_code in _timestamp_type_cache:
return _timestamp_type_cache[unit_code]
_timestamp_type_cache[unit_code] = out
else:
if not isinstance(tz, six.string_types):
tz = tz.zone
c_timezone = tobytes(tz)
out.init(ctimestamp(unit_code, c_timezone))
return out
def time32(unit):
"""
Create instance of 32-bit time (time of day) type with unit resolution
Parameters
----------
unit : string
one of 's' [second], or 'ms' [millisecond]
Examples
--------
::
t1 = pa.time32('s')
t2 = pa.time32('ms')
"""
cdef:
TimeUnit unit_code
c_string c_timezone
if unit == "s":
unit_code = TimeUnit_SECOND
elif unit == 'ms':
unit_code = TimeUnit_MILLI
else:
raise ValueError('Invalid TimeUnit for time32: {}'.format(unit))
cdef Time32Type out
if unit_code in _time_type_cache:
return _time_type_cache[unit_code]
else:
out = Time32Type()
out.init(ctime32(unit_code))
_time_type_cache[unit_code] = out
return out
def time64(unit):
"""
Create instance of 64-bit time (time of day) type with unit resolution
Parameters
----------
unit : string
one of 'us' [microsecond], or 'ns' [nanosecond]
Examples
--------
::
t1 = pa.time64('us')
t2 = pa.time64('ns')
"""
cdef:
TimeUnit unit_code
c_string c_timezone
if unit == "us":
unit_code = TimeUnit_MICRO
elif unit == 'ns':
unit_code = TimeUnit_NANO
else:
raise ValueError('Invalid TimeUnit for time64: {}'.format(unit))
cdef Time64Type out
if unit_code in _time_type_cache:
return _time_type_cache[unit_code]
else:
out = Time64Type()
out.init(ctime64(unit_code))
_time_type_cache[unit_code] = out
return out
def date32():
"""
Create instance of 32-bit date (days since UNIX epoch 1970-01-01)
"""
return primitive_type(_Type_DATE32)
def date64():
"""
Create instance of 64-bit date (milliseconds since UNIX epoch 1970-01-01)
"""
return primitive_type(_Type_DATE64)
def float16():
"""
Create half-precision floating point type
"""
return primitive_type(_Type_HALF_FLOAT)
def float32():
"""
Create single-precision floating point type
"""
return primitive_type(_Type_FLOAT)
def float64():
"""
Create double-precision floating point type
"""
return primitive_type(_Type_DOUBLE)
cpdef DataType decimal(int precision, int scale=0):
"""
Create decimal type with precision and scale
Parameters
----------
precision : int
scale : int
Returns
-------
decimal_type : DecimalType
"""
cdef shared_ptr[CDataType] decimal_type
decimal_type.reset(new CDecimalType(precision, scale))
return pyarrow_wrap_data_type(decimal_type)
def string():
"""
Create UTF8 variable-length string type
"""
return primitive_type(_Type_STRING)
def binary(int length=-1):
"""
Create variable-length binary type
Parameters
----------
length : int, optional, default -1
If length == -1 then return a variable length binary type. If length is
greater than or equal to 0 then return a fixed size binary type of
width `length`.
"""
if length == -1:
return primitive_type(_Type_BINARY)
cdef shared_ptr[CDataType] fixed_size_binary_type
fixed_size_binary_type.reset(new CFixedSizeBinaryType(length))
return pyarrow_wrap_data_type(fixed_size_binary_type)
cpdef ListType list_(value_type):
"""
Create ListType instance from child data type or field
Parameters
----------
value_type : DataType or Field
Returns
-------
list_type : DataType
"""
cdef:
DataType data_type
Field field
shared_ptr[CDataType] list_type
ListType out = ListType()
if isinstance(value_type, DataType):
list_type.reset(new CListType((<DataType> value_type).sp_type))
elif isinstance(value_type, Field):
list_type.reset(new CListType((<Field> value_type).sp_field))
else:
raise ValueError('List requires DataType or Field')
out.init(list_type)
return out